We had the task-force of loading Flex modules in AIR application at runtime. All our flex modules are developed already and they can run well in our website; but loading the Flex modules and make them run in AIR is the different story, the problem comes from the different security mechanism between AIR and Web Flex application. The Flex module can not be loaded by using class mx.modules.ModuleManager though we tried to modify crossdomain.xml file and modify some stuffs in flex module. We search the solutions on internet and there are only 3 valuable resources discuss exactly the problem we faces, they are:

• [1] - The work-around solution: http://weblogs.macromedia.com/emalasky/archives/2008/04/remote_plugins.html
• [2] - The proposed solution but not complete: http://weblogs.macromedia.com/emalasky/archives/2008/04/remote_plugins.html
• [3] - Another solution using AIR Update framework: http://www.intriguemedia.net/2008/02/22/loading-modulesruntime-css-into-an-air-app/

The first work-around solution is tricky, we see it as the last solution if we can not seek the better one (within 2 days). We also do not prefer the third solution because we do not want to use AIR Update framework because we want to deploy our application as SaaS model, that means we do not know how many services we have to bundle them all at the first time also we would like to have right that force people update (such as security pack, bug fix pack like OS without user confirm whether it is necessary or not). The comments of third solution is exact our solution when we combine them with the solution of [2], they solve completely our problem in several lines of code!

I would like to summarize our steps to solve the problem (Copy from [2], temporarily not sign our modules and verify the the signature. They should be presented in our future works)

1. Download the remote module and store them in AIR application storage:

   //Load the remote module base on moduleUri -
   //for example: http://www.esofthead.com/engroup/HrEmployeeModule.swf
   var loader:URLLoader = new URLLoader();
   loader.dataFormat = URLLoaderDataFormat.BINARY;
   loader.addEventListener(Event.COMPLETE, moduleLoadedCompleteHandler);
   loader.addEventListener(IOErrorEvent.IO_ERROR, moduleLoaderErrorHandler);
   loader.load(new URLRequest(moduleUri))

   Save module into application storage when the module is completely downloaded

   private function moduleLoadedCompleteHandler(e:Event): void {
       var loader:URLLoader = URLLoader(e.target);
       var data:ByteArray = ByteArray(loader.data);
       var moduleFile:File = File.applicationStorageDirectory.resolvePath("HrEmployeeModule.swf");
       var fileStream:FileStream = new FileStream();
       fileStream.open(moduleFile, FileMode.WRITE);
       fileStream.writeBytes(data);
       fileStream.close();
   }

2. Load the module (in application storage)

   var moduleLoader:Loader = new Loader();
   var context:LoaderContext = new LoaderContext();
   context.allowLoadBytesCodeExecution = true;
   context.applicationDomain = ApplicationDomain.currentDomain;    
    
   //data is byte array of module, it could be filled by loading 
    
   //bytes from local file (module file is stored in app storage)
   moduleLoader.loadBytes(data, context);
   moduleLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeLoader);

   We process module when it is already loaded

   private function completeLoader(e:Event): void {
       var moduleLoader:LoaderInfo = LoaderInfo(e.target);
       moduleLoader.content.addEventListener("ready", readyHandler);
   }

3. Use module when the module is already loaded

   private function readyHandler(e:Event): void {
       var factory:IFlexModuleFactory = IFlexModuleFactory(e.target);
       var module:Module = factory.create() as Module;
       // Do as flex module as usual
       ...
   }

Note that you can control the loading remote module and cache module by using AIR embedded database. The database should keep url, version of module (our AIR only download the remote module if it does not exist in local or it has the newer version in server side). And we can develop the Service Management at client side to keep track the life cycle of each application services, that allows we can uninstall/install/update with/or without user knowledge.